/**
 * cellularautomata.java
 * part of cellularAutomata
 *
 * Used to visualize Cellular Automata system
 *
 * written by Matthew Shanley
 * matthewshanley@littlesecretsrecords.com
 */

import oscP5.*;

// Variables for World and Beings
//static final int RECT_SIZE = 10;
static final int RECT_SIZE = 20;
static final int STATE_REPORT_BLOCK_SIZE = 10;
World myWorld;
Being[] myBeings;

// Variables for 2 oscP5 instances (local and remote)
static final float OSC_SEND_DELAY = 1000;   // Time to wait between sending OSC state in milliseconds
OscP5 localOscP5;
OscP5 remoteOscP5;
int localReceiveAtPort;
int remoteReceiveAtPort;
int localSendToPort;
int remoteSendToPort;
String localHost;
String remoteHost;
String oscP5event;
float timeLastOscSend;

void setup() {
    // Initializations 
    //size(500, 500);
    size(800, 600);
    colorMode(HSB, 360, 100, 100);
    background(0);
    loop();
    ellipseMode(CORNER);
    // World constructor takes: int initWidth, int initHeight, int initNumThoughtWords
    myWorld = new World((width/RECT_SIZE), (height/RECT_SIZE), 350);
    myBeings = new Being[50];
    for (int i=0; i<myBeings.length; i++) {
	// Being constructor takes: World initWorld, float collectorChance
	myBeings[i] = new Being(myWorld, 0.75);
    }
    //    initOsc();
}

void draw() {
    // Update myBeings which might change world
    for (int i=0; i<myBeings.length; i++) {
	myBeings[i].takeLeaveThoughtWord();
	myBeings[i].move();
    }

    // Display Sites
    int numThoughtWords;
    String[] allThoughtWordTypes;
    for (int i=0; i<(width/RECT_SIZE); i++) {
	for (int j=0; j<(height/RECT_SIZE); j++) {
	    noStroke();
	    numThoughtWords = myWorld.getSite(i,j).getNumThoughtWords();
	    allThoughtWordTypes = myWorld.getSite(i,j).getAllThoughtWordTypes();
	    if (numThoughtWords == 0) {   // Site with no words
		fill(0, 0, 80);
		rect(i*RECT_SIZE, j*RECT_SIZE, RECT_SIZE, RECT_SIZE);
	    } else {   // Site with a pile of words on it
		if (allThoughtWordTypes[0] == "selfconscious") {   // breathing
		    //fill(0, 50+numThoughtWords*50, 0);
		    for (int x=0; x<min(numThoughtWords, RECT_SIZE); x++) {
			//fill(0, 255-((255/RECT_SIZE)*x), 0);   // old - for RGB
			fill(85, 100, 100-((100/RECT_SIZE)*x));
			rect(i*RECT_SIZE+x, j*RECT_SIZE+x, RECT_SIZE-2*x, RECT_SIZE-2*x);
		    }
		} else {   // feedback
		    //fill(0, 0, 50+numThoughtWords*50);
		    for (int x=0; x<min(numThoughtWords, RECT_SIZE); x++) {
			fill(195, 100, 100-((100/RECT_SIZE)*x));
			rect(i*RECT_SIZE+x, j*RECT_SIZE+x, RECT_SIZE-2*x, RECT_SIZE-2*x);
		    }
		}
	    }
	}
    }

    // Display Beings
    for (int i=0; i<myBeings.length; i++) {
	stroke(0, 0, 0);
	// Check role of beings for coloring
	// Role can be collector or disperser
	if (myBeings[i].getRole().equals("collector")) {
	    //fill(255, 255, 205);
	    fill(60, 30, 100);
	} else {
	    //fill(255, 205, 205);
	    fill(0, 30, 100);
	}
	ellipse(myBeings[i].getXpos()*RECT_SIZE, myBeings[i].getYpos()*RECT_SIZE, RECT_SIZE, RECT_SIZE);
    }

    // Send out current state through OSC by rate OSC_SEND_DELAY
    /*    if (timeLastOscSend+OSC_SEND_DELAY < millis()) {
	oscSendState();
	timeLastOscSend = millis();
	}	*/
}

// Initialize OSC
void initOsc() {
    localReceiveAtPort = 12000;
    remoteReceiveAtPort = 12001;
    localSendToPort = 57120;
    remoteSendToPort = 57121;
    localHost = "127.0.0.1";
    remoteHost = "192.168.1.102";   // THIS NEEDS TO BE SET
    oscP5event = "oscEvent";   // as far as I can tell it doesn't really matter what this is

    localOscP5 = new OscP5(
			   this,
			   localHost,
			   localSendToPort,
			   localReceiveAtPort,
			   oscP5event);
    remoteOscP5 = new OscP5(
			    this,
			    remoteHost,
			    remoteSendToPort,
			    remoteReceiveAtPort,
			    oscP5event);
    timeLastOscSend = millis();
}

void oscEvent(OscIn oscIn) {
    println("received something ...");
}

void oscSendState() {
    /* 
     * Send a message to local and remote Pd patches
     * Communicating current state of world.
     *
     * Break the world up into STATE_REPORT_BLOCK_SIZE size squares,
     * and send out two messages:
     * the number of selfconscious and of memory ThoughtWords
     * in each square.
     */

    // address patterns of the messages
    String apSC = "/caselfconscious";
    String apM = "/camemory";
    Object[] objSC = new Object[(((width/RECT_SIZE)/STATE_REPORT_BLOCK_SIZE)*((height/RECT_SIZE)/STATE_REPORT_BLOCK_SIZE))];
    Object[] objM = new Object[(((width/RECT_SIZE)/STATE_REPORT_BLOCK_SIZE)*((height/RECT_SIZE)/STATE_REPORT_BLOCK_SIZE))];

    // Determine the arguments of the messages
    int scCounter;
    int mCounter;
    boolean containsSC;
    boolean containsM;
    int iStart;
    int jStart;
    String[] allThoughtWordTypes;
    
    for (int arrayPos=0; arrayPos<(((width/RECT_SIZE)/STATE_REPORT_BLOCK_SIZE)*((height/RECT_SIZE)/STATE_REPORT_BLOCK_SIZE)); arrayPos++) {
	scCounter = 0;
	mCounter = 0;
	containsSC = false;
	containsM = false;
	iStart = (int)(arrayPos/((width/RECT_SIZE)/STATE_REPORT_BLOCK_SIZE));
	jStart = (int)(arrayPos%((height/RECT_SIZE)/STATE_REPORT_BLOCK_SIZE));
	for (int i=iStart; i<iStart+STATE_REPORT_BLOCK_SIZE; i++) {
	    for (int j=jStart; j<jStart+STATE_REPORT_BLOCK_SIZE; j++) {
		allThoughtWordTypes = myWorld.getSite(i, j).getAllThoughtWordTypes();
		for (int x=0; x<myWorld.getSite(i,j).getNumThoughtWords(); x++) {
		    if (allThoughtWordTypes[x] == "selfconscious") {
			containsSC = true;
		    } else if (allThoughtWordTypes[x] == "memory") {
			containsM = true;
		    } else {
			println("Problem with ThoughtWordType when counting");
		    }
		}
		if (containsSC) { scCounter++; }
		if (containsM) { mCounter++; }
	    }
	}
	objSC[arrayPos] = new Integer(scCounter);
	objM[arrayPos] = new Integer(mCounter);
    }

    // send the messages
    localOscP5.sendMsg(apSC, objSC);
    remoteOscP5.sendMsg(apSC, objSC);
    localOscP5.sendMsg(apM, objM);
    remoteOscP5.sendMsg(apM, objM);
}